IF  EXISTS (SELECT * FROM dbo.sysobjects WHERE id = OBJECT_ID(N'[dbo].[SPUSS_102_HIZMET_KAYIT]') AND OBJECTPROPERTY(id,N'IsProcedure') = 1)
DROP PROCEDURE SPUSS_102_HIZMET_KAYIT
GO

CREATE PROCEDURE [dbo].[SPUSS_102_HIZMET_KAYIT] 
	@HDOSYAID INT=0,
	@HESAPISLID INT=0,
	@TUMUNUTEKRAR BIT = 0	 
AS
BEGIN
	--SPUSS_102_HIZMET_KAYIT 160253,0,1
	DECLARE @HATA NVARCHAR(2000) = ''
	DECLARE @MESAJ NVARCHAR(2000) = ''
	DECLARE @SAYIHATA BIT = 0
	DECLARE @XMLBASLIK NVARCHAR(2000) = ''
	DECLARE @SUBEID INT = 1
	DECLARE @goNDERIMTABLOSU TABLE 
		(
			goNDERILECEKXML XML,
			HATA NVARCHAR(2000),
			MESAJ NVARCHAR(2000),	
			XMLBASLIK NVARCHAR(3500),
			TABLOID INT,
			MINID INT,
			MAXID INT
		)


	IF OBJECT_ID('tempdb..#TMPDOSYA') IS NOT NULL 
		DROP TABLE #TMPDOSYA
	IF OBJECT_ID('tempdb..#TMPISLEMLER') IS NOT NULL 
		DROP TABLE #TMPISLEMLER
	IF OBJECT_ID('tempdb..#TMPYUZISLEM') IS NOT NULL 
		DROP TABLE #TMPYUZISLEM
	IF OBJECT_ID('tempdb..#TMPGENISLEMBILGISI') IS NOT NULL 
		DROP TABLE #TMPGENISLEMBILGISI

    
	SELECT 
		HDOSYA.SUBEID AS HDOSYA_SUBEID,
		SUBELER.SUBEADI AS SUBELER_SUBEADI,
		HDOSYA.SNOTAKIPNO AS HDOSYA_SNOTAKIPNO,		
		ISNULL((SELECT TOP 1 VALUESTR FROM CONFIG WITH(NOLOCK) WHERE SECTIONSTR='Saglik-Net' AND PROGNAME='MEDISOFT' AND KEYNAME= CONVERT(VARCHAR,HDOSYA.SUBEID)+' numaralı şubenin kurum numarası'),'') AS SAGLIKNETKURUMKODU				
	INTO #TMPDOSYA
	FROM
		HDOSYA WITH(NOLOCK)
		LEFT JOIN SUBELER WITH(NOLOCK) ON SUBELER.SUBEID = HDOSYA.SUBEID
	WHERE
		HDOSYA.HDOSYAID = @HDOSYAID	

	
	SELECT 
		TKLINIKIST.KLINIKKODU AS TKLINIK_KLINIKKODU,
		TKLINIKIST.KLINIKADI  AS TKLINIK_KLINIKADI,
		TITEM.ITEMTURUID AS TITEM_ITEMTURUID,		
		TITEM.BARKOD AS TITEM_BARKOD,
		TITEM.UBBKODU AS TITEM_UBBKODU,
		CASE WHEN ISNULL(TITEM.ITEMKODU2_LOINC,'')<>'' AND ITEMKODU2_LOINC_BASTRH<=DBO.TARIHAL(HESAPISL.ITARIH) THEN ITEMKODU2_LOINC ELSE TITEM.ITEMKODU2 END AS TITEM_ITEMKODU2,
		TITEM.ITEMADI2 AS TITEM_ITEMADI2,

		
		
		CASE WHEN CHARINDEX(cast(HESAPISL.HESAPISLID as nvarchar(MAX)), (SELECT STUFF((SELECT ',' + CAST(HESAPISLID_LISTESI AS nvarchar(MAX)) FROM HAKILCIISTEMMUKERRERLIK (NOLOCK) WHERE HDOSYAID =  @HDOSYAID FOR XML PATH('') ), 1, 1, ''))  )>0
		         AND (SELECT MAX(SORGULAMATARIHI) FROM HAKILCIISTEMMUKERRERLIK (NOLOCK) WHERE HDOSYAID =  @HDOSYAID) IS NOT NULL 
				 AND (SELECT MAX(SORGULAMATARIHI) FROM HAKILCIISTEMMUKERRERLIK (NOLOCK) WHERE HDOSYAID =  @HDOSYAID)> HESAPISL.ITARIH 
				 AND (SELECT MAX(MANUELSORGU) FROM HAKILCIISTEMMUKERRERLIK (NOLOCK) WHERE HDOSYAID =  @HDOSYAID)='1' 
		
		         THEN (SELECT DATEADD(MINUTE,1, MAX(SORGULAMATARIHI)) FROM HAKILCIISTEMMUKERRERLIK (NOLOCK) WHERE HDOSYAID = @HDOSYAID)		 

		ELSE
			HESAPISL.ITARIH END  AS HESAPISL_ITARIH,
		
		HESAPISL.ADET AS HESAPISL_ADET,		
		HESAPISL.HESAPISLID AS HESAPISL_HESAPISLID,
		[USER].TCKIMLIKNO AS USER_TCKIMLIKNO,
		TDRKIMLIK.DRTCKIMLIKNO AS TDRKIMLIK_DRTCKIMLIKNO,
		HMALZILAC.TARAFTIPI AS HMALZILAC_TARAFTIPI,
		HMUAYENE.AMLONERILDI AS HMUAYENE_AMLONERILDI,
		HMUAYENE.HMAMELIYATTRH AS HMUAYENE_HMAMELIYATTRH,
		HTETKIK.DISTETKIK AS HTETKIK_DISTETKIK
	INTO #TMPISLEMLER	
	FROM HESAPISL WITH(NOLOCK)    
     INNER JOIN TITEM WITH(NOLOCK) ON HESAPISL.ITEMID = TITEM.ITEMID  
	 LEFT  JOIN HDOSYA WITH(NOLOCK) ON HESAPISL.HDOSYAID =HDOSYA.HDOSYAID   
	 LEFT JOIN TBOLUM TBOLUMIST WITH(NOLOCK) ON HESAPISL.ISTBOLUMID = TBOLUMIST.BOLUMID    
     LEFT JOIN TKLINIK TKLINIKIST WITH(NOLOCK) ON TBOLUMIST.KLINIKKODU = TKLINIKIST.KLINIKKODU 
     LEFT JOIN TDRKIMLIK WITH(NOLOCK) ON HESAPISL.ISTDRID = TDRKIMLIK.DRID    
     LEFT JOIN HMUAYENEISL WITH(NOLOCK) ON HESAPISL.HESAPISLID = HMUAYENEISL.HESAPISLID    
     LEFT JOIN HMUAYENE WITH(NOLOCK) ON HMUAYENEISL.HMUAYENEID = HMUAYENE.HMUAYENEID    
     LEFT JOIN HTETKIK WITH(NOLOCK) ON HESAPISL.HESAPISLID = HTETKIK.HESAPISLID    
     LEFT JOIN HMALZILAC WITH(NOLOCK) ON HESAPISL.HESAPISLID = HMALZILAC.HESAPISLID    
     LEFT JOIN HUYGISLEM WITH(NOLOCK) ON HESAPISL.HESAPISLID = HUYGISLEM.HESAPISLID    
     LEFT JOIN HYATIS WITH(NOLOCK) ON HESAPISL.HESAPISLID = HYATIS.HESAPISLID    
     LEFT JOIN HAMELIYAT WITH(NOLOCK) ON HESAPISL.HESAPISLID = HAMELIYAT.HESAPISLID    
     LEFT JOIN [USER] WITH(NOLOCK) ON HESAPISL.KYKULLANICI = [USER].KODU 	   
	WHERE HESAPISL.IPTAL = 0    
		  AND HESAPISL.ONAYLI = 1    
		  AND HESAPISL.TEKLIF = 0    
		  AND HESAPISL.SNKAYDET = 1    
		  AND CASE TABLOTIPI    
				  WHEN 0    
				  THEN HMUAYENEISL.DURUM    
				  WHEN 1    
				  THEN HTETKIK.DURUM    
				  WHEN 2    
				  THEN HMALZILAC.DURUM    
				  WHEN 3    
				  THEN HUYGISLEM.DURUM    
				  WHEN 4    
				  THEN HYATIS.DURUM    
				  WHEN 5    
				  THEN HAMELIYAT.DURUM    
			  END < 3    
		  AND TKLINIKIST.KLINIKKODU IS NOT NULL
		  AND HDOSYA.HDOSYAID = @HDOSYAID
		  AND (@HESAPISLID=0 OR HESAPISL.HESAPISLID = @HESAPISLID)
		  AND (@TUMUNUTEKRAR=1 OR (@TUMUNUTEKRAR=0 AND ISNULL(HESAPISL.SNOgoNDERILDI,0)=0))
	ORDER BY HESAPISL.HESAPISLID

	SELECT
	   HTETKIKGENLIST.GENKODU AS GENKODU, 
	   TITEM.ITEMKODU2 AS ISLEMKODU
	INTO #TMPGENISLEMBILGISI
	FROM HESAPISL WITH(NOLOCK) 
		INNER JOIN TITEM WITH(NOLOCK) ON HESAPISL.ITEMID = TITEM.ITEMID 
		LEFT  JOIN HDOSYA WITH(NOLOCK) ON HESAPISL.HDOSYAID =HDOSYA.HDOSYAID
		LEFT JOIN HTETKIK WITH(NOLOCK) ON HESAPISL.HESAPISLID = HTETKIK.HESAPISLID 
		LEFT JOIN HTETKIKGENLIST  WITH(NOLOCK) ON HTETKIK.HTETKIKID = HTETKIKGENLIST.HTETKIKID
	WHERE HESAPISL.IPTAL = 0    
		  AND HESAPISL.ONAYLI = 1    
		  AND HESAPISL.TEKLIF = 0    
		  AND HESAPISL.SNKAYDET = 1		
		  AND HTETKIKGENLIST.GENKODU IS NOT NULL 
		  AND LEFT(TITEM.ITEMKODU2_LOINC,1)='G'  
		  AND HDOSYA.HDOSYAID = @HDOSYAID
		  AND (@HESAPISLID=0 OR HESAPISL.HESAPISLID = @HESAPISLID)
		  AND (@TUMUNUTEKRAR=1 OR (@TUMUNUTEKRAR=0 AND ISNULL(HESAPISL.SNOgoNDERILDI,0)=0))
	ORDER BY HESAPISL.HESAPISLID

	IF (SELECT COUNT(*) FROM #TMPGENISLEMBILGISI)=0
	BEGIN
		DELETE FROM #TMPGENISLEMBILGISI
	END
		      
	IF (SELECT COUNT(*) FROM #TMPISLEMLER) = 0
	BEGIN
		SET @SAYIHATA = 1 
		SET @MESAJ = @MESAJ + 'gonderilecek tetkik bulunmadı'
	END

	IF (SELECT COUNT(*) FROM #TMPDOSYA WHERE HDOSYA_SUBEID IS NULL) > 0 
		SET @HATA = @HATA + 'İşlemin şube kaydı bulunamadı! '

	IF (SELECT HDOSYA_SUBEID FROM #TMPDOSYA WHERE ISNULL(HDOSYA_SNOTAKIPNO,'')='') > 0 
		SET @HATA = @HATA + 'Sağlık Net hasta takip numarası alınmadan USS sistemine hizmet, ilaç/malzeme kaydı yapılamaz. '

	IF @HATA='' AND @SAYIHATA=0
	BEGIN		
		SELECT @SUBEID = HDOSYA_SUBEID FROM #TMPDOSYA
		DECLARE @TBLXMLBASLIK TABLE (XMLBASLIK NVARCHAR(2000), HATA NVARCHAR(2000),MESAJ NVARCHAR(2000))
		INSERT INTO @TBLXMLBASLIK (XMLBASLIK, HATA, MESAJ) EXEC SPUSS_000_XML_BASLIK @SUBEID		
		SELECT @HATA=@HATA+HATA, @MESAJ=@MESAJ+MESAJ, @XMLBASLIK=XMLBASLIK FROM @TBLXMLBASLIK		
	END

	IF @HATA = '' AND @SAYIHATA = 0
	BEGIN
	

		DECLARE @HIZMETSAYI INT = (SELECT COUNT(HESAPISL_HESAPISLID) FROM #TMPISLEMLER)
		DECLARE @HIZMETDONUSSAYISI INT = CEILING(@HIZMETSAYI*1.0/750)
		DECLARE @MINHESAPISLID INT = 0
		DECLARE @MAXHESAPISLID INT = 0


		WHILE @HIZMETDONUSSAYISI>0
		BEGIN
			SET @HIZMETDONUSSAYISI = @HIZMETDONUSSAYISI - 1

			IF OBJECT_ID('tempdb..#TMPYUZISLEM') IS NOT NULL 
				DROP TABLE #TMPYUZISLEM
		
			SELECT TOP 750 * INTO #TMPYUZISLEM FROM #TMPISLEMLER WHERE HESAPISL_HESAPISLID>@MAXHESAPISLID  ORDER BY HESAPISL_HESAPISLID
			SET @MINHESAPISLID = (SELECT MIN(HESAPISL_HESAPISLID) FROM #TMPYUZISLEM)	
			SET @MAXHESAPISLID = (SELECT MAX(HESAPISL_HESAPISLID) FROM #TMPYUZISLEM)
		



					
							BEGIN TRY

								INSERT INTO @goNDERIMTABLOSU (goNDERILECEKXML,HATA,MESAJ,XMLBASLIK,TABLOID,MINID,MAXID)
								SELECT							 
									(

											SELECT 
												NEWID() AS 'messageGuid/@value',
												'1' AS 'messageType/@version',
												'0a9ba485-e7e0-4abb-9c86-0a14fd364bb8' AS 'messageType/@codeSystemGuid' ,
												'102' AS 'messageType/@code',
												'Hizmet/Ilaç/Malzeme Bilgisi Kayıt' AS 'messageType/@value' ,
												LEFT(REPLACE(REPLACE(REPLACE(CONVERT(VARCHAR(19),GETDATE(),120),' ',''),'-',''),':',''),12) AS  'documentGenerationTime/@value',
												(	 
													 SELECT
														'1' AS  'healthcareProvider/@version',
														 'c3eade04-4f91-5dab-e043-14031b0ac9f9' AS  'healthcareProvider/@codeSystemGuid',
														SAGLIKNETKURUMKODU AS 'healthcareProvider/@code',
														SUBELER_SUBEADI as 'healthcareProvider/@value'  
													 FOR XML PATH('author'), TYPE
												  ),
												  'C740D0288ED4C45FE0407C0A04162BDD'  AS 'firmaKodu/@value',
												  (

													 SELECT--RECORT DATA
														(
															SELECT
															   ISNULL(HDOSYA_SNOTAKIPNO,'') AS 'SYSTakipNo/@value'
															FOR XML PATH('HASTA_TAKIP_BILGISI'), TYPE
														),
														(
															SELECT--HASTA_ISLEM_BILGILERI
															   (
																  SELECT--ISLEM_BILGISI 
																	'1' AS 'TARAF_BILGISI/@version',
																	 '05c03e8c-79fd-461e-8b78-99c3cfad011e' AS 'TARAF_BILGISI/@codeSystemGuid' ,
																	 (CASE HMALZILAC_TARAFTIPI 
																		WHEN 1 THEN '1'
																		WHEN 2 THEN '2'
																		ELSE '3' END) AS 'TARAF_BILGISI/@code', 
																	 (CASE HMALZILAC_TARAFTIPI 
																		WHEN 1 THEN 'SAĞ'
																		WHEN 2 THEN 'SOL'
																		ELSE 'SAĞ-SOL BELIRSIZ' END) AS 'TARAF_BILGISI/@value',
																		(CASE HMUAYENE_AMLONERILDI 
																		WHEN 1 THEN ISNULL(LEFT(REPLACE(REPLACE(REPLACE(CONVERT(VARCHAR(19),HESAPISL_ITARIH,120),' ',''),'-',''),':',''),12),'')
																		ELSE '' END) AS 'HEKIMIN_AMELIYATA_KARAR_VERDIGI_TARIH/@value',
																	ISNULL(LEFT(REPLACE(REPLACE(REPLACE(CONVERT(VARCHAR(19),HMUAYENE_HMAMELIYATTRH,120),' ',''),'-',''),':',''),12),'') AS 'AMELIYAT_RANDEVU_TARIHI/@value',
																	

																	CASE WHEN ISNULL(HTETKIK_DISTETKIK,0) = 0 THEN 'KURUM İÇİ'  ELSE 'DIŞ HİZMET ALIMI' END  AS 'HIZMET_ALIM_BILGISI/@value',
																	'1' AS 'HIZMET_ALIM_BILGISI/@version',																	
																	'2571ca21-163d-440c-bbd7-6e6ba1697a05' AS 'HIZMET_ALIM_BILGISI/@codeSystemGuid',
																	CASE WHEN ISNULL(HTETKIK_DISTETKIK,0) = 0 THEN  3 ELSE 1 END AS 'HIZMET_ALIM_BILGISI/@code',



																	 '1' AS 'KLINIK_KODU/@version',
																	 'c04bee57-c5d4-443d-e040-7b0a6f146a3d' AS 'KLINIK_KODU/@codeSystemGuid' ,
																	 TKLINIK_KLINIKKODU AS 'KLINIK_KODU/@code', 
																	 TKLINIK_KLINIKADI AS 'KLINIK_KODU/@value',

																	 --İşlem Gerçekleşme Zamanı bilgisi(istek zamanı gönderilmemelidir). örn:"201409231403"
																	 LEFT(REPLACE(REPLACE(REPLACE(CONVERT(VARCHAR(19),HESAPISL_ITARIH,120),' ',''),'-',''),':',''),12) AS 'GERCEKLESME_ZAMANI/@value',
												 
																	 '1' AS 'ISLEM_TURU/@version',
																	 'd03e562d-252e-451f-9a80-98d48b47c2f2' AS 'ISLEM_TURU/@codeSystemGuid',
																	  ISNULL((SELECT CASE 
																			  WHEN TITEM_ITEMTURUID = 3
																				  THEN 2
																			  WHEN TITEM_ITEMTURUID = 5
																				  THEN 3
																			  ELSE 1
																	   END),'') AS 'ISLEM_TURU/@code',											
																	  ISNULL((SELECT CASE 
																			   WHEN TITEM_ITEMTURUID = 3
																			   THEN 'İLAÇ'
																			   WHEN TITEM_ITEMTURUID = 5
																			   THEN 'MALZEME'
																			   ELSE 'DIĞER (SUT, VAKA BAŞI VEYA PAKET IŞLEMLER)'
																			   END),'')
																			   AS 'ISLEM_TURU/@value',

																		--İşlem Kod bilgisi, hizmetler için Sağlık Uygulama Tebliği Listesi kodları, İlaç için Barkod bilgisi , SGK ödemeye tabii malzemeler için SUT Kodu , SGK ödemeye tabii olmayan malzemeler için Barkod bilgisi gönderilecektir.
																		ISNULL(TITEM_ITEMKODU2,'') AS 'ISLEM_KODU/@value',				
																		ISNULL(TITEM_ITEMADI2,'') AS 'ISLEM_ADI/@value',

																		--Yapılan işlemin Girişimsel İşlem Listesindeki kodu gönderilecektir. örn:'520030'
																		ISNULL(TITEM_ITEMKODU2,'') AS 'GIRISIMSEL_ISLEM_KODU/@value',

																		--İşlem Tarih bilgisi(istem tarihi gönderilmelidir). örn:"201405280912"
																		ISNULL(LEFT(REPLACE(REPLACE(REPLACE(CONVERT(VARCHAR(19),HESAPISL_ITARIH,120),' ',''),'-',''),':',''),12),'') AS 'ISLEM_ZAMANI/@value',
													
																		--İşlem Adet bilgisi hizmetler için adet bilgisi, ilaç ve malzeme için MKYS de kayıtlı birime göre miktar bilgisi
																		ISNULL(CONVERT(VARCHAR(20), CAST(HESAPISL_ADET AS money), 1),'') AS 'ADET/@value',

																		--Hasta dosyasina islenen islemin hasta yansiyan Hasta Tutar bilgisi. örn:"15.50" BU VERI ELAMANINI OZEL VE UNIVERSITE HASTANELERININ goNDERMESINE GEREK YOKTUR.
																		ISNULL(CONVERT(VARCHAR(20), CAST(0 AS MONEY), 1),'') AS  'HASTA_TUTARI/@value',

																		--Hasta dosyasina islenen islemin hastanin sosyal güvencesinin bulundugu kuruma yansiyan Kurum Tutar bilgisi. örn:"15.50" BU VERI ELAMANINI OZEL VE UNIVERSITE HASTANELERININ goNDERMESINE GEREK YOKTUR.
																		ISNULL(CONVERT(VARCHAR(20), CAST(0 AS MONEY), 1),'') AS 'KURUM_TUTARI/@value',
													
																		--İşlemin Randevu Zamanı bilgisi. örn:"201403140900"
																		ISNULL(LEFT(REPLACE(REPLACE(REPLACE(CONVERT(VARCHAR(19),HESAPISL_ITARIH,120),' ',''),'-',''),':',''),12),'') AS 'RANDEVU_ZAMANI/@value',
																		'' AS 'DONOR_ALICI_KIMLIK_NUMARASI/@value',

																		--İşlemi hasta dosyasına işleyen Kullanıcı Kimlik Numarası bilgisi
																		ISNULL(USER_TCKIMLIKNO,ISNULL(TDRKIMLIK_DRTCKIMLIKNO,'')) AS 'KULLANICI_KIMLIK_NUMARASI/@value',
													
																		--İşlemin yapıldığı Cihaz Numarası, MKYS sistemindeki barkod numarası
																		'' AS 'CIHAZ_NUMARASI/@value',

																		--İşlemin hizmet sunucusuna özel tekil Referans Numarası bilgisi
																		ISNULL(HESAPISL_HESAPISLID,'') AS 'ISLEM_REFERANS_NUMARASI/@value',

																		(
																			SELECT 
																			   ISNULL(TDRKIMLIK_DRTCKIMLIKNO,'') AS 'HEKIM_KIMLIK_NUMARASI/@value',
																			   '0.00' AS 'ISLEM_PUANI/@value',
																			   ISNULL(LEFT(REPLACE(REPLACE(REPLACE(CONVERT(VARCHAR(19),HESAPISL_ITARIH,120),' ',''),'-',''),':',''),12),'' ) AS 'PUAN_HAKEDIS_ZAMANI/@value'							
																			FOR XML PATH('ISLEM_HEKIM_BILGISI'), TYPE
																		),
																		(
																			SELECT 
																						'1' AS 'GEN_KODU/@version',
																						'5db9b171-50bb-4180-9d2e-67f35148ff82' AS 'GEN_KODU/@codeSystemGuid',
																						GENKODU AS 'GEN_KODU/@code',
																						'' AS 'GEN_KODU/@value'
																				FROM #TMPGENISLEMBILGISI
																			FOR XML PATH('GEN_ISLEM_BILGISI'),TYPE)
																	
																		FROM #TMPYUZISLEM
																  FOR XML PATH('ISLEM_BILGISI'), TYPE
															   )
															FOR XML PATH('HASTA_ISLEM_BILGILERI'), TYPE
														)
												  FOR XML PATH('recordData'), TYPE
											  )
	
										FROM #TMPDOSYA 

										FOR XML PATH (''), ROOT('SYSMessage')

									) AS goNDERILECEKXML,
									@HATA AS HATA, 
									@MESAJ AS MESAJ,
									@XMLBASLIK AS XMLBASLIK,
									@HESAPISLID AS TABLOID,
									@MINHESAPISLID AS MINID,
									@MAXHESAPISLID AS MAXID

							END TRY
							BEGIN CATCH
								SET @HATA = ERROR_MESSAGE()
								IF @HATA = ''
									SET @HATA = 'Bilinmeyen bir hata oluştu'

								INSERT INTO @goNDERIMTABLOSU (goNDERILECEKXML,HATA,MESAJ,XMLBASLIK,TABLOID,MINID,MAXID)
								SELECT	'' AS goNDERILECEKXML,
										@HATA AS HATA, 
										@MESAJ AS MESAJ,
										'' AS XMLBASLIK,
										@HESAPISLID AS TABLOID,
										0 AS MINID,
										0 AS MAXID
			

							END CATCH				


		END --DONGU SON

	END
	ELSE
	BEGIN

		INSERT INTO @goNDERIMTABLOSU (goNDERILECEKXML,HATA,MESAJ,XMLBASLIK,TABLOID,MINID,MAXID)
		SELECT	'' AS goNDERILECEKXML,
				@HATA AS HATA, 
				@MESAJ AS MESAJ,
				'' AS XMLBASLIK,
				@HESAPISLID AS TABLOID,
				0 AS MINID,
				0 AS MAXID	

		SET @HATA = ''	 
	END


	
	IF OBJECT_ID('tempdb..#TMPDOSYA') IS NOT NULL 
		DROP TABLE #TMPDOSYA
	IF OBJECT_ID('tempdb..#TMPYUZISLEM') IS NOT NULL 
		DROP TABLE #TMPYUZISLEM
	IF OBJECT_ID('tempdb..#TMPISLEMLER') IS NOT NULL 
		DROP TABLE #TMPISLEMLER


	SELECT * FROM @goNDERIMTABLOSU


END

