IF  EXISTS (SELECT * FROM dbo.sysobjects WHERE id = OBJECT_ID(N'[dbo].[SPUSS_303_IZLEM_SIL]') AND OBJECTPROPERTY(id,N'IsProcedure') = 1)
DROP PROCEDURE SPUSS_303_IZLEM_SIL
GO


CREATE PROCEDURE [dbo].[SPUSS_303_IZLEM_SIL] 
	@HDOSYAID INT=0,
	@HYIZLEMID INT=0,
	@TUMUNUTEKRAR BIT = 0	 
AS
BEGIN
	--SPUSS_303_IZLEM_SIL 3439329,54659290,1
	DECLARE @HATA NVARCHAR(2000) = ''
	DECLARE @MESAJ NVARCHAR(2000) = ''
	DECLARE @SAYIHATA BIT = 0
	DECLARE @XMLBASLIK NVARCHAR(2000) = ''
	DECLARE @SUBEID INT = 1
	DECLARE @GONDERIMTABLOSU TABLE 
		(
			GONDERILECEKXML XML,
			HATA NVARCHAR(2000),
			MESAJ NVARCHAR(2000),	
			XMLBASLIK NVARCHAR(3500),
			TABLOID INT,
			MINID INT,
			MAXID INT
		)


	IF OBJECT_ID('tempdb..#TMPDOSYA') IS NOT NULL 
		DROP TABLE #TMPDOSYA
	IF OBJECT_ID('tempdb..#TMPOZELLIKLIIZLEM') IS NOT NULL 
		DROP TABLE #TMPOZELLIKLIIZLEM




	SELECT 
		HDOSYA.SUBEID AS HDOSYA_SUBEID,
		SUBELER.SUBEADI AS SUBELER_SUBEADI,
		HDOSYA.SNOTAKIPNO AS HDOSYA_SNOTAKIPNO,		
		ISNULL((SELECT TOP 1 VALUESTR FROM CONFIG WITH(NOLOCK) WHERE SECTIONSTR='Saglik-Net' AND PROGNAME='MEDISOFT' AND KEYNAME= CONVERT(VARCHAR,HDOSYA.SUBEID)+' numaralı şubenin kurum numarası'),'') AS SAGLIKNETKURUMKODU				
	INTO #TMPDOSYA
	FROM
		HDOSYA WITH(NOLOCK)
		LEFT JOIN SUBELER WITH(NOLOCK) ON SUBELER.SUBEID = HDOSYA.SUBEID
	WHERE
		HDOSYA.HDOSYAID = @HDOSYAID		
		

	SELECT HYIZLEM.HYIZLEMID AS HYIZLEM_HYIZLEMID,			
			HYIZLEM.HYATISID AS HYIZLEM_HYATISID,		
			HYIZLEM.YBHESAPISLID AS HYIZLEM_YBHESAPISLID,
			HYIZLEM.IZLEM AS HYIZLEM_IZLEM,		    
			HYIZLEM.TARIH AS HYIZLEM_TARIH		
	INTO #TMPOZELLIKLIIZLEM
	FROM		HYATIS
	INNER JOIN	HYIZLEM ON HYIZLEM.HYATISID = HYATIS.HYATISID
	INNER JOIN HYOZELLIKLIIZLEM ON HYOZELLIKLIIZLEM.HYIZLEMID=HYIZLEM.HYIZLEMID
    INNER JOIN HDOSYA ON HDOSYA.HDOSYAID=HYATIS.HDOSYAID
	WHERE HYATIS.HDOSYAID = @HDOSYAID
	--	AND (@HYIZLEMID=0 OR HYIZLEM.HYIZLEMID = @HYIZLEMID)
	--	AND (@TUMUNUTEKRAR=1 OR (@TUMUNUTEKRAR=0 AND ISNULL(HYIZLEM.OZELLIKLIIZLEMGONDERILDI,0)=1))
	--	AND DBO.TARIHAL(HDOSYA.GSSCIKISTARIHI)>HYIZLEM.TARIH 
	ORDER BY KAYITTARIHI DESC
	

			      
	IF (SELECT COUNT(*) FROM #TMPOZELLIKLIIZLEM) = 0
	BEGIN
		SET @SAYIHATA = 1 
		SET @MESAJ = @MESAJ + 'Silinecek izlem bulunmadı'
	END

	IF (SELECT COUNT(*) FROM #TMPDOSYA WHERE HDOSYA_SUBEID IS NULL) > 0 
		SET @HATA = @HATA + 'İşlemin şube kaydı bulunamadı! '

	IF (SELECT HDOSYA_SUBEID FROM #TMPDOSYA WHERE ISNULL(HDOSYA_SNOTAKIPNO,'')='') > 0 
		SET @HATA = @HATA + 'Sağlık Net hasta takip numarası alınmadan USS sistemine izlem silme yapılamaz. '

	IF @HATA='' AND @SAYIHATA=0
	BEGIN		
		SELECT @SUBEID = HDOSYA_SUBEID FROM #TMPDOSYA
		DECLARE @TBLXMLBASLIK TABLE (XMLBASLIK NVARCHAR(2000), HATA NVARCHAR(2000),MESAJ NVARCHAR(2000))
		INSERT INTO @TBLXMLBASLIK (XMLBASLIK, HATA, MESAJ) EXEC SPUSS_000_XML_BASLIK @SUBEID		
		SELECT @HATA=@HATA+HATA, @MESAJ=@MESAJ+MESAJ, @XMLBASLIK=XMLBASLIK FROM @TBLXMLBASLIK		
	END

	IF @HATA = '' AND @SAYIHATA = 0
	BEGIN
	

					
							BEGIN TRY

								INSERT INTO @GONDERIMTABLOSU (GONDERILECEKXML,HATA,MESAJ,XMLBASLIK,TABLOID,MINID,MAXID)
								SELECT							 
									(

											SELECT 
												NEWID() AS 'messageGuid/@value',
												'1' AS 'messageType/@version',
												'0a9ba485-e7e0-4abb-9c86-0a14fd364bb8' AS 'messageType/@codeSystemGuid' ,
												'303' AS 'messageType/@code',
												'Izlem Silme' AS 'messageType/@value' ,
												LEFT(REPLACE(REPLACE(REPLACE(CONVERT(VARCHAR(19),GETDATE(),120),' ',''),'-',''),':',''),12) AS  'documentGenerationTime/@value',
												(	 
													 SELECT
														'1' AS  'healthcareProvider/@version',
														 'c3eade04-4f91-5dab-e043-14031b0ac9f9' AS  'healthcareProvider/@codeSystemGuid',
														SAGLIKNETKURUMKODU AS 'healthcareProvider/@code',
														SUBELER_SUBEADI as 'healthcareProvider/@value'  
													 FOR XML PATH('author'), TYPE
												  ),
												  'C740D0288ED4C45FE0407C0A04162BDD'  AS 'firmaKodu/@value',
												  (

													 SELECT--RECORT DATA
														(
															SELECT
															   ISNULL(HDOSYA_SNOTAKIPNO,'') AS 'SYSTakipNo/@value'
															FOR XML PATH('HASTA_TAKIP_BILGISI'), TYPE
														),
														(
															SELECT
																	(															
																		SELECT
																		   ISNULL(HYIZLEM_HYIZLEMID,'') AS 'IZLEM_REFERANS_NUMARASI/@value'
																		FROM #TMPOZELLIKLIIZLEM
																		FOR XML PATH('SILINECEK_IZLEM'), TYPE 
																	)
															FOR XML PATH('SILINECEK_IZLEM_BILGISI'), TYPE
														)
												  FOR XML PATH('recordData'), TYPE
											  )
	
										FROM #TMPDOSYA 

										FOR XML PATH (''), ROOT('SYSMessage')

									) AS GONDERILECEKXML,
									@HATA AS HATA, 
									@MESAJ AS MESAJ,
									@XMLBASLIK AS XMLBASLIK,
									@HYIZLEMID AS TABLOID,
									'' AS MINID,
									'' AS MAXID

							END TRY
							BEGIN CATCH
								SET @HATA = ERROR_MESSAGE()
								IF @HATA = ''
									SET @HATA = 'Bilinmeyen bir hata oluştu'

								INSERT INTO ZAMANLAYICIHATALARI (HDOSYAID,ISLEMKODU,TABLOID,HATAVEREN,HATAKODU,HATA,MESAJ,OLUSTURULMAZAMANI)
								SELECT @HDOSYAID,'303',@HYIZLEMID,'SP','',@HATA,@MESAJ,GETDATE()
							
								INSERT INTO @GONDERIMTABLOSU (GONDERILECEKXML,HATA,MESAJ,XMLBASLIK,TABLOID,MINID,MAXID)
								SELECT	'' AS GONDERILECEKXML,
										@HATA AS HATA, 
										@MESAJ AS MESAJ,
										'' AS XMLBASLIK,
										@HYIZLEMID AS TABLOID,
										0 AS MINID,
										0 AS MAXID
			

							END CATCH				


		

	END
	ELSE
	BEGIN
		IF @HATA<>''
			INSERT INTO ZAMANLAYICIHATALARI (HDOSYAID,ISLEMKODU,TABLOID,HATAVEREN,HATAKODU,HATA,MESAJ,OLUSTURULMAZAMANI)
			SELECT @HDOSYAID,'303',@HDOSYAID,'SP','',@HATA,@MESAJ,GETDATE()

		INSERT INTO @GONDERIMTABLOSU (GONDERILECEKXML,HATA,MESAJ,XMLBASLIK,TABLOID,MINID,MAXID)
		SELECT	'' AS GONDERILECEKXML,
				@HATA AS HATA, 
				@MESAJ AS MESAJ,
				'' AS XMLBASLIK,
				@HYIZLEMID AS TABLOID,
				0 AS MINID,
				0 AS MAXID	

		SET @HATA = ''	 
	END


	
	IF OBJECT_ID('tempdb..#TMPDOSYA') IS NOT NULL 
		DROP TABLE #TMPDOSYA

	IF OBJECT_ID('tempdb..#TMPOZELLIKLIIZLEM') IS NOT NULL 
		DROP TABLE #TMPOZELLIKLIIZLEM


	SELECT * FROM @GONDERIMTABLOSU


END
